Structured Canvas Language™ - Make games easily

SCL™ Basics

Here is a step-by-step walk-through to create the sample to the left.

Step 1

create routine as Start
  launch ball
end

create sprite from ballbottom.png as preload1 end
create sprite from 8ball.png as ball
  where x=400 y=300 click=Touched center=250,250
end
create sprite from window.png as window
  where x=0 y=0 center=70,70 alpha=1 click=Touched
end
create sprite from windowback.png as windowback
  where x=0 y=0 center=70,70
end
create sprite from triangle.png as triangle
  where x=0 y=0 center=70,70
end

create routine as Touched
	update sprite ball where click=_none
	update sprite window where click=_none
	update sprite window where alpha=1
  insert into ball where alt=WiggleLeft
  insert into ball where alt=RotLeft
  draw onto triangle
    clear
  enddraw
end

create var as WiggleCount where value=0 completion=WiggleDone condition=5 end

create slide as WiggleLeft
  where speed=600 distance=40 direction=220 completion=WiggleLeftDone
end

create routine as WiggleLeftDone
  insert into ball where alt=WiggleRight
end

create slide as WiggleRight
  where speed=600 distance=40 direction=45 completion=WiggleRightDone
end

create rotation as RotLeft
  where distance=20 speed=800 completion=RotLeftDone
end

create routine as RotLeftDone
  insert into ball where alt=RotRight
end

create rotation as RotRight
  where distance=20 speed=-800
end

create routine as WiggleRightDone
	update var WiggleCount add=1
  insert into ball where alt=WiggleLeft
  insert into ball where alt=RotLeft
end

create translation as TransToCenter
	where x=400 y=300 speed=400 completion=ShowPrediction
end

create routine as WiggleDone
	insert into ball where alt=TransToCenter
  remove from ball where alt=WiggleLeft
  remove from ball where alt=RotLeft
	update sprite ball where image=ballbottom.png
	insert into ball where children=(windowback,triangle,window)
end

create data from list as Text
set
	"Concentrate" "and ask" "again"
	"Have you" "lost your" "mind?"
	"Doesn't" "seem" "likely"
	"" "Doubtful" ""
	"" "Yes" ""
	"" "No" ""
	"Ask" "again" "later"
	"Almost" "no" ""
	"All cats" "agree:" "Yes"
	"Only" "if on" "Tuesday"
	"Definitely" "yes" ""
end

create routine as ShowPrediction
	insert into ball where alt=(sub create rotation where destination=0 speed=-100 end)
	insert into window where alt=(sub create fade where until=0.1 rate=-1 end)
	var line1=data.Text.select.3
	var line2=data.Text.next
	var line3=data.Text.next

draw onto triangle
		font "20px/25px sans-serif"
		textalign "center"
		fillstyle "#ffffff"
		filltext line1,70,5,320
		filltext line2,70,30,100
		filltext line3,70,55,100
		fill
	enddraw
	update sprite ball where click=Touched
	update sprite window where click=Touched
	update var WiggleCount set=0
	update var WiggleCount reset
end