Structured Canvas Language™ - Make games easily

SCL™ Basics

Finally we add the predictions. We take them from a data list which defines each individual line of each prediction and we draw them on the triangle.

create routine as Start
  launch ball
end

create sprite from 8ball.png as ball
  where x=400 y=300 center=250,250 click=Touched
end

create routine as Touched
  insert into ball where alt=WiggleLeft
  insert into ball where alt=RotLeft
end

create var as WiggleCount where value=0 completion=WiggleDone condition=5 end

create slide as WiggleLeft
  where speed=600 distance=40 direction=220 completion=WiggleLeftDone
end

create slide as WiggleRight
  where speed=600 distance=40 direction=45 completion=WiggleRightDone
end

create rotation as RotLeft
  where distance=20 speed=800 completion=RotLeftDone
end

create routine as RotLeftDone
  insert into ball where alt=RotRight
end

create rotation as RotRight
  where distance=20 speed=-800
end

create routine as WiggleLeftDone
  insert into ball where alt=WiggleRight
end

create routine as WiggleRightDone
	update var WiggleCount add=1
  insert into ball where alt=WiggleLeft
  insert into ball where alt=RotLeft
end

create routine as WiggleDone
  remove from ball where alt=WiggleLeft
  remove from ball where alt=RotLeft
  update sprite ball where image=ballbottom.png
	insert into ball where children=(windowback,triangle,window)
  insert into ball where alt=TransToCenter
	insert into ball where alt=(sub create rotation where destination=0 speed=-100 end)
	insert into window where alt=(sub create fade where until=0.1 rate=-1 end)
end

create sprite from ballbottom.png end
create sprite from window.png as window
  where x=0 y=0 center=70,70 alpha=1
end
create sprite from windowback.png as windowback
  where x=0 y=0 center=70,70
end
create sprite from triangle.png as triangle
  where x=0 y=0 center=70,70
end

create translation as TransToCenter
	where x=400 y=300 speed=400 completion=ShowPrediction
end

create data from list as Text
set
	"Concentrate" "and ask" "again"
	"Have you" "lost your" "mind?"
	"Doesn't" "seem" "likely"
	"" "Doubtful" ""
	"" "Yes" ""
	"" "No" ""
	"Ask" "again" "later"
	"Almost" "no" ""
	"All cats" "agree:" "Yes"
	"Only" "if on" "Tuesday"
	"Definitely" "yes" ""
end

create routine as ShowPrediction
	var line1=data.Text.select.3
	var line2=data.Text.next
	var line3=data.Text.next

draw onto triangle
		font "20px/25px sans-serif"
		textalign "center"
		fillstyle "#ffffff"
		filltext line1,70,5,320
		filltext line2,70,30,100
		filltext line3,70,55,100
		fill
	enddraw
end

editable

create data from list is used to create 'Text'. This contains a list of text where each prediction is three lines long. If a prediction is less than three lines, then define blanks "".
ShowPrediction randomly chooses a three line prediction using the 'data' function select. The trailing '.3' indicates the data is grouped in rows of three. data.Text.next chooses the next value in the list. To summarize: "choose a random string from every third entry in the data set, then get the next two entries".
Once the prediction is created, we draw it onto the triangle.